10 REM >TelProb
   20 REM by Steven Flintham
   30 REM
   40 REM Demonstrate the problem with combining single and double height text
   50 REM
   60 REM Monday 7th September 1992
   70 :
   80 MODE 7
   90 VDU 23;8202;0;0;0;
  100 PROCdisable
  110 PROCinit
  120 PROCdemonstrate
  130 MODE 7
  140 PROCenable
  150 END
  160 :
  170 DEF PROCdisable
  180 *FX229,1
  190 *FX4,2
  200 ENDPROC
  210 :
  220 DEF PROCenable
  230 *FX229,0
  240 *FX4,0
  250 ENDPROC
  260 :
  270 DEF PROCinit
  280 ON ERROR MODE 7:REPORT:PRINT " at line ";ERL:PROCenable:END
  290 ENDPROC
  300 :
  310 DEF PROCdemonstrate
  320 PROCproblem_demo
  330 PRINTTAB(0,0);"Vers. 1.00";TAB(32,0);CHR$135;"(C) SGF"
  340 PRINTTAB(0,3);"This shows the style of combined heading";
  350 PRINT "which works. The important point is that";
  360 PRINT "the single height text is on the same"
  370 PRINT "line as the TOP of the double height"
  380 PRINT "text."
  390 PROCspace
  400 CLS
  410 PROCproblem_demo
  420 PRINTTAB(0,1);"Vers. 1.00";TAB(32,1);CHR$135;"(C) SGF"
  430 PRINTTAB(0,3);"This shows that the same style does not"
  440 PRINT "work if the single height text is on the";
  450 PRINT "same line as the bottom half of the"
  460 PRINT "double height text. Examination of the"
  470 PRINT "program will show that the text is still";
  480 PRINT "being printed, even though it does not"
  490 PRINT "appear."
  500 PROCspace
  510 ENDPROC
  520 :
  530 DEF PROCspace
  540 PRINTTAB(6,24);CHR$131;"Press SPACE to continue...";
  550 *FX21
  560 REPEAT UNTIL GET=32
  570 ENDPROC
  580 :
  590 DEF PROCproblem_demo
  600 PRINTTAB(10,0);CHR$141;CHR$132;CHR$157;CHR$131;"Problem Demo  ";CHR$156;CHR$140;
  610 PRINTTAB(10,1);CHR$141;CHR$132;CHR$157;CHR$131;"Problem Demo  ";CHR$156;CHR$140;
  620 ENDPROC