10 REM >TitlTop
   20 REM by Steven Flintham
   30 REM
   40 REM A demonstration of one style of mode 7 display.
   50 REM
   60 REM Sunday 6th September 1992
   70 :
   80 MODE 7
   90 VDU 23;8202;0;0;0;
  100 PROCdisable
  110 PROCinit
  120 PROCshow_style
  130 PROClist_program
  140 PROCenable
  150 END
  160 :
  170 DEF PROCdisable
  180 *FX229,1
  190 *FX4,2
  200 ENDPROC
  210 :
  220 DEF PROCinit
  230 ON ERROR MODE 7:REPORT:PRINT " at line ";ERL:PROCenable:END
  240 ENDPROC
  250 :
  260 DEF PROCenable
  270 *FX229,0
  280 *FX4,0
  290 ENDPROC
  300 :
  310 DEF PROCshow_style
  320 PROCtitle("Mode 7 layout demonstration",3,4)
  330 PRINTTAB(7,24);CHR$131;"(C) Steven Flintham 1992";TAB(0,3);
  340 PRINT "This is a demonstration of one of the"
  350 PRINT "simplest mode 7 screen layouts. However,it can be very effective and does leave"
  360 PRINT "a lot of the screen free for the programto use."
  370 PRINT'"Note that the heading and text at the"
  380 PRINT "bottom of the screen are both correctly"
  390 PRINT "centered. When centering in mode 7, it"
  400 PRINT "is important to allow for the space"
  410 PRINT "taken up by the control codes -"
  420 PRINT "especially in 'reversed' areas like the"
  430 PRINT "heading."
  440 PRINT'"Using a text window can avoid problems"
  450 PRINT "with scrolling. Press SPACE to"
  460 PRINT "demonstrate this."
  470 *FX21
  480 REPEAT UNTIL GET=32
  490 ENDPROC
  500 :
  510 DEF PROCtitle(title$,fore%,back%)
  520 LOCAL x%
  530 x%=20-LEN(title$)/2
  540 PRINTTAB(x%-4,0);CHR$141;CHR$(128+back%);CHR$157;CHR$(128+fore%);title$;"  ";CHR$156
  550 PRINTTAB(x%-4,1);CHR$141;CHR$(128+back%);CHR$157;CHR$(128+fore%);title$;"  ";CHR$156
  560 ENDPROC
  570 :
  580 DEF PROClist_program
  590 VDU 28,0,22,39,3
  600 CLS
  610 *FX138,0,76
  620 *FX138,0,73
  630 *FX138,0,83
  640 *FX138,0,84
  650 *FX138,0,13
  660 ENDPROC