10 MODE0
   20 PRINT"Put 4 Mode 0 screens into 1 and save back to disc."
   30 PRINT"By C.J.Richardson for 8-Bit Software."
   40 PRINT"Insert the four screen names into the data statements"
   50 PRINT"at the end of this program. Put the save name for the"
   60 PRINT"finished screen in the last DATA statement. Then RUN"
   70 PRINT"this program and wait."''"PRESS A KEY"
   80 REPEATUNTILGET
   90 DEFFNS="Shrink"
  100 CLS
  110 REPEAT
  120 P%=0
  130 READS%,A$
  140 IF A$="END":READ Name$:OSCLI"SA. "+Name$+" 3000 8000":END
  150 F%=OPENIN A$
  160 FORY%=1TO16
  170 FORX%=1TO40
  180 PROCg
  190 PTR#F%=PTR#F%+&278
  200 PROCg
  210 PTR#F%=PTR#F%-&278
  220 NEXT
  230 P%=P%+320:IF Y%<>16:PTR#F%=PTR#F%+&280
  240 NEXT
  250 CLOSE#F%
  260 UNTILA$="END"
  270 END
  280 DEFPROCget_byte
  290 A%=BGET#F%
  300 IF A%>127 A%=A%-128:T%=128 ELSE T%=0
  310 IF A%-32>-1 A%=A%-32:T%=T%+64
  320 IF A%-8>-1 A%=A%-8:T%=T%+32
  330 IF A%-2>-1 A%=A%-2:T%=T%+16
  340 PTR#F%=PTR#F%+7
  350 A%=BGET#F%
  360 IF A%>127 A%=A%-128:T%=T%+8
  370 IF A%-32>-1 A%=A%-32:T%=T%+4
  380 IF A%-8>-1 A%=A%-8:T%=T%+2
  390 IF A%-2>-1 A%=A%-2:T%=T%+1
  400 PTR#F%=PTR#F%-7
  410 ENDPROC
  420 DEFPROCg
  430 FORL%=1TO4
  440 PROCget_byte
  450 ?(P%+S%)=T%
  460 P%=P%+1
  470 M%=M%+1
  480 NEXT
  490 ENDPROC
  500 DATA &3000
  510 DATA Screen name 1 here
  520 DATA &3140
  530 DATA Screen name 2 here
  540 DATA &5800
  550 DATA Screen name 3 here
  560 DATA &5940
  570 DATA Screen name 4 here
  580 DATA 0,END
  590 DATA Save name here