10 DEFFNS="3DEye-2"
   20  REM ON ERROR PROCsave:END
   30 REM MAGIC3D by L Knight May 1994
   40 REM Adapted by D.Lowless
   50 REM Further modified by C.J.Richardson
   60 MODE1:DIMA%(60):DIMB%(60)
   70 R%=3
   80 REPEAT
   90 CLS
  100 PRINT''"3D Magic Eye."'"Originally by Lorin Knight."'"Adapted By D.Lowless."
  110 PRINT"Finally modified by C.J.Richardson."
  120 PRINT''"1. Use Demo Screen."
  130 PRINT"2. Load screen."
  140 PRINT"3. *LDPIC a Screen."
  150 PRINT"4. Toggle Depth direction. Now ";:IF R%=3 PRINT"out." ELSE PRINT"in."
  160 PRINT''"Please Enter 1 2 3 or 4. "
  170 *FX21
  180 A$=GET$
  190 IF A$="4" IF R%=3 R%=0 ELSE IF A$="4" R%=3
  200 UNTILINSTR("123",A$)
  210 CLS
  220 IF A$="1" PROCtext
  230 IF A$="2":OSCLI".":INPUT'"Screen to Load? "B$:OSCLI"LO. "+B$+" FFFF3000"
  240 IF A$="3":OSCLI".":INPUT'"Screen to *LDPIC? "B$:OSCLI"LDPIC "+B$
  250 REMmed out for BBC compatibility *FX108,2
  260 REMmed out for BBC compatibility  *FX112,0
  270 REMmed out for BBC compatibility  *FX113,0
  280 FORY%=1023 TO 0 STEP -4
  290 E%=15:C%=0
  300 FORN%=0TO60:A%(N%)=RND(2)-1:NEXT
  310 FORX%=0TO1279STEP4
  320 REMmed out for BBC compatibility *FX112,2
  330 D%=ABS(R%-(POINT(X%,Y%)))*2
  340 REMmed out for BBC compatibility *FX112,0
  350 L%=D%+45:F%=E%+45
  360 IFE%>D% PROCforward:GOTO390
  370 IFE%<D% PROCback:GOTO390
  380 P%=(C%+1)MOD(L%+1)
  390 GCOL0,A%(P%)*3:PLOT69,X%,Y%
  400 C%=P%:E%=D%:NEXT:NEXT
  410 PROCsave
  420 PRINTTAB(0,0)" COMPLETED "'SPC11:VDU7
  430 END
  440  
  450 DEFPROCforward
  460 I%=E%-D%
  470 FORN%=0TOF%:B%(N%)=A%((N%+C%+1)MOD(F%+1)):NEXT
  480 FORN%=0TOL%:A%(N%)=B%(N%+I%):NEXT
  490 P%=0
  500 ENDPROC
  510  
  520 DEFPROCback
  530 I%=D%-E%
  540 FORN%=0TOF%:B%(N%)=A%((N%+C%+1)MOD(F%+1)):NEXT
  550 FORN%=I%TOL%:A%(N%)=B%(N%-I%):NEXT
  560 FORN%=0TO(I%-1):A%(N%)=RND(2)-1:NEXT
  570 P%=0:ENDPROC
  580  
  590  DEFPROCsave
  600  REM *FX108,0
  610  *SAVE FIN FFFF3000+5000
  620  ENDPROC
  630 REM
  640 DEFPROCtext
  650  VDU23,224,126,126,126,126,126,126,126,126
  660  PROCbig(850,"   Magic",1,140)
  670  PROCbig(650,"    Eye",2,140)
  680  PROCbig(450,"   8-Bit",3,140)
  690  PROCbig(250,"  Software",1,129)
  700 VDU4
  710 ENDPROC
  720 DEF PROCbig(T%,a$,C%,H%)
  730  GCOL 0,C%
  740 VDU 5
  750 FOR Z%=1 TO LEN(a$)
  760 ?&900=ASC(MID$(a$,Z%,1))
  770 X%=0:Y%=9:A%=&A:CALL&FFF1
  780 FOR W%=1 TO 8:FOR U%=7 TO 0 STEP -1
  790 IF W%?&900 AND 2^U% MOVE (Z%-1)*H%+(7-U%)*17,T%+(9-W%)*20:VDU 224
  800 NEXT:NEXT:NEXT:VDU 4
  810 ENDPROC