20 ONERRORGOTO30
   30 REPEAT
   35 VDU3:MODE7:CLOSE#0
   40 *FX18
   50 *DIR $
  160 *FX6,0
  170 *FX4,0
  240 CLS:PRINTCHR$132;CHR$157;CHR$130;CHR$141;"      DFS UTILITIES MENU"
  250 PRINTCHR$132;CHR$157;CHR$130;CHR$141;"      DFS UTILITIES MENU"
  300 PRINT
  310 PRINTTAB(6)"1.  File loader"
  340 PRINTTAB(6)"2.  Backup discs"
  370 PRINTTAB(6)"3.  Format discs"
  380 PRINTTAB(6)"4.  Verify discs"
  410 PRINTTAB(6)"5.  Alter directories"
  420 *FX21,0
  440 PRINT
  450 PRINTTAB(0)"ƒ         Option ? ";:A=GET
  460 IFA=42THENPROCoscommand
  462 IFA=49THEN690
  464 IFA=50THEN600
  466 IFA=51THENPROCformat
  468 IFA=52THENPROCverify
  469 IFA=53THENPROCcd
  500 IFA<42ORA>53THENPROChelp
  522 UNTILFALSE
  540  
  600  PAGE=O%:CHAIN"$.BACKUP"
  690  CHAIN"$.LOADER"
  720  
  730 DEFPROCcd
  740 CLS:PRINT"ƒAlter directories "
  745 PROCdrivenumber
  746 OSCLI("DIR :"+DRI$)
  748 REPEAT
  750 CLS:*.
  770 PRINTTAB(0,21)"Alter dir1 ? "
  775 D1$=GET$
  776 IFD1$>"/"ANDD1$<"4"THENOSCLI("DIR :"+D1$):GOTO750
  780 PRINTTAB(0,21)"ƒAlter ";D1$;"dir2 ? "
  785 D2$=GET$
  786 PRINTTAB(0,21)"ƒAlter ";D1$;" ";D2$;"      "
  790 C$="CD "+D1$+" "+D2$
  800 PRINTTAB(0,23)"ƒPress RETURN if O.K."
  810 Q$=GET$:IFQ$=CHR$(13)THENOSCLI(C$)
  822 UNTILFALSE
  824 ENDPROC  
  830  
  900 DEFPROCoscommand
  910 CLS:VDU15
  920 INPUT"ƒ*"C$
  930 IFC$=""THENENDPROC
  940 OSCLI(C$)
  950 PROCend:ENDPROC
 1000  
 2000 DEFPROCformat
 2002 CLS:PRINT"ƒFormat 40 or 80 track ? ";
 2005 T$="":A=GET
 2010 IFA=52THENT$="40"
 2015 IFA=56THENT$="80"
 2020 IF T$="" THEN2000ELSEPRINT"ƒ";T$
 2040 PROCdrivenumber
 2092 PRINT"ƒ";DRI$
 2094 PRINT'"ƒFORM ";T$;" ";DRI$
 2100 OSCLI("FORM+V "+T$+" "+DRI$)
 2110 PROCend:ENDPROC
 2120  
 2200 DEFPROCverify
 2210 CLS:PRINT"ƒVerify "; 
 2230 PROCdrivenumber
 2250 PRINT"ƒ";DRI$
 2260 PRINT'"ƒVERIFY ";DRI$ 
 2270 OSCLI("V "+DRI$)
 2280 PROCend:ENDPROC
 2290  
 2500 DEFPROCdrivenumber
 2510 PRINTTAB(0,2)"ƒwhich drive ? ";
 2520 REPEAT:DRI$="":A=GET
 2530 IFA=48THENDRI$="0"
 2540 IFA=49THENDRI$="1"
 2550 IFA=50THENDRI$="2"
 2560 IFA=51THENDRI$="3"
 2562 UNTILLEN(DRI$)
 2570 ENDPROC 
 2600 DEFPROCend
 2610 PRINT'"…PRESS ANY KEY ":B=GET
 2620 ENDPROC
 2700 DEFPROChelp
 2710 CLS:PRINT
 2712 PRINT"****** Help for the Control Menu ******"
 2714 PRINT'"esc..Return to the control menu"
 2716 PRINT'"*..Enter os commands"
 2718 PRINT'"1..File Loader has its own help file"
 2720 PRINT'"2..Fast backup of used tracks only "
 2722 PRINT"   using compact first speeds it up "
 2724 PRINT'"3..Formats and Verifies 40/80 T disks"
 2726 PRINT"   If any errors are reported then "
 2728 PRINT"   bin that disk."
 2730 PRINT'"4..Verifies a disks tracks/sectors."
 2732 PRINT"   If any errors are reported then "
 2734 PRINT"   copy files to another disk and try"
 2736 PRINT"   reformat before consigning this to"
 2738 PRINT"   the dustbin."
 2740 PRINT'"5..Moves all files from one directory"
 2742 PRINT"   to another on selected drive."
 2790 A=GET:ENDPROC