10 REM Random Word Generator
   20 REM (C) 1996 Jon Ripley
   30 REM This program is PD
   40 REM Please DO NOT ALTER this program
   50 DEFFNS="WordGen"
   60 MODE 7
   70 FORX=1TO2:PRINTTAB(0,X)CHR$141;CHR$(127+2*X)"Random Word Generator (C) Jon Ripley":NEXT
   80 VDU28,0,24,39,4
   90 PRINT"If you have Superior Software's Speech! Loaded I can attempt to say the words I make."''"If Speech! is not loaded enter 'N'."'"Say words (Y/N):";
  100 REPEATA$=GET$:UNTILINSTR("YyNn",A$)
  110 IF INSTR("Yy",A$) say=TRUE ELSE say=FALSE
  120 CLS
  130 ONERRORIF ERR=254 say=FALSE ELSE MODE7:END
  140 VDU14
  150 A=RND(-TIME)
  160 v$="aeiou"
  170 c$="bcdfghjklmpqrstvwxyzn"
  180 x$=""
  190 REPEAT
  200 REPEAT
  210 w$=""
  220 c=RND(21)
  230 w$=w$+CHR$(ASC(MID$(c$,c,1))-32)
  240 IFc=12w$=w$+"u"
  250 IFc=15ANDRND(5)=1w$=w$+"h"
  260 w$=w$+FNv
  270 UNTILRND(15)<2
  280 REPEAT
  290 c=RND(21)
  300 w$=w$+MID$(c$,c,1)
  310 IFRND(15)=1w$=w$+MID$(c$,c,1)
  320 IFc=12w$=w$+"u"
  330 IFc=15ANDRND(9)=1w$=w$+"h"
  340 IFc=2ANDRND(2)=1w$=w$+"k"
  350 IFc<>12ANDRND(15)=1w$=w$+"r"
  360 UNTILRND(5)<4
  370 IFRND(9)<5w$=w$+FNv
  380 IFINSTR(v$,RIGHT$(w$,1))w$=w$+x$
  390 PRINTw$
  400 IF say OSCLI"*Say "+w$
  410 UNTIL.
  420 DEFFNv
  430 y$=x$
  440 REPEAT
  450 v=RND(5)
  460 x$=MID$(v$,v,1)
  470 UNTILx$<>y$
  480 =x$