2 REM Monthly diary B.RAW K6N 1997
   10 *TV255
   20 *FX18
   30 *FX21
   40 *KEY10"*EXEC !BOOT|M"
   50 *FX4,1
   60 *FX229,1
   70 *FX225,200
   80 *FX226,210
   90 *FX227,220
  100 MODE7
  110 DIM M$(12),dd%(12,2)
  120 RESTORE
  130 FOR I=1TO12:READM$(I),dd%(I,2):NEXT
  140 fm$="  JanFebMarAprMayJunJulAugSepOctNovDec"
  150 epson%=0
  160 sysclk%=0
  170 year%=0:L%=1:P%=1
  180 ONERROR:GOTO210
  190 F%=OPENIN"Mdata":INPUT#F%,year%,L%,P%,epson%,sysclk%:CLOSE#F%
  200 PROCgetSDs
  210 ONERROR:VDU7:RUN
  220 VDU23;10,&60;0;0;0
  230 PROCstart
  240 PROCinit
  250 :
  260 REPEAT
  270 REPEAT
  280 H%=0
  290 $W%="M"+MID$(fm$,P%*3,3)
  300 VDU30,157,129
  310 PRINT"<H>elp <I>ndex <P>rint <['> <Esc> [ ] "
  320 PRINTTAB(0,1)CHR$(157)CHR$(133)"        "M$(P%)"   "STR$(year%)
  330 PROCload
  340 REPEAT
  350 Q%=GET
  360 UNTILINSTR("HIPhip",CHR$(Q%))ORQ%=13ORQ%=27ORQ%>135
  370 IFQ%>127:T%=0
  380 IFQ%=72ORQ%=104:PROChelp1
  390 IFQ%=73ORQ%=105:PROCindex
  400 IFQ%=80ORQ%=112:PROCvprint
  410 IFQ%=27:RUN
  420 IFQ%=136:L%=L%-1
  430 IFQ%=137:L%=L%+1
  440 IFQ%=138:P%=P%-1:L%=1
  450 IFQ%=139:P%=P%+1:L%=1
  460 IFL%<1:P%=P%-1:L%=1
  470 IFL%>max%:L%=1:P%=P%+1
  480 IFP%<1:P%=12:L%=1
  490 IFP%>12:P%=1:L%=1
  500 UNTILQ%=13 AND H%=0
  510 VDU30:PRINT$&A00:PRINTTAB(2,6);
  520 E%=E%EOR1:VDU23,1,E%;0;0;0;
  530 REPEAT
  540 a%=GET:A%=a%
  550 IFA%<>27:PROCkeys
  560 UNTILA%=27
  570 PROCsave
  580 E%=E%EOR1:VDU23,1,E%;0;0;0;
  590 UNTILFALSE
  600 :
  610 DEFPROCvprint
  620 VDU30:PRINT$&A00:VDU30,9,9
  630 PROCprint
  640 ENDPROC
  650 :
  660 DEFPROCkeys
  670 IFA%=16:PROCprint:ENDPROC
  680 IFA%=3:PROCnewpage:ENDPROC
  690 IFA%=13ANDVPOS=24:VDU7:ENDPROC
  700 IFA%=13:VDU10,13,8:PROCright:ENDPROC
  710 IFINSTR("QWASZXqwaszx",CHR$(a%))<>0ANDt%:PROCpixel:ENDPROC
  720 IFA%=136:PROCleft:ENDPROC
  730 IFA%=137:PROCright:ENDPROC
  740 IFA%=138:PROCdown:ENDPROC
  750 IFA%=139:PROCup:ENDPROC
  760 IFa%>=200ANDa%<=229:PROCfkeys
  770 IFA%=127:PROCdelete:ENDPROC
  780 IFA%=226:PROCinspc:ENDPROC
  790 REM IFA%=227:PROCinsline:ENDPROC
  800 REM IFA%=228:PROCdelline:ENDPROC
  810 IFA%=209ORA%=219ORA%=229:PROCptog:ENDPROC
  820 IFE%=0:VDU7:ENDPROC
  830 IFVPOS=24ANDPOS=39ANDt%=0:?(&7C27+40*24)=A%:VDU7:ENDPROC
  840 IFt%=0ANDA%>31:VDUA%,8:PROCright
  850 ENDPROC
  860 :
  870 DEFPROCfkeys
  880 IFa%>=200ANDa%<=208:A%=a%-71
  890 IFa%>=210ANDa%<=216:A%=a%-65
  900 IFa%>=217ANDa%<=218:A%=a%-61
  910 IFa%>=220ANDa%<=221:A%=a%-67
  920 IFa%>=222ANDa%<=223:A%=a%-64
  930 IFa%>=224ANDa%<=225:A%=365-a%
  940 ENDPROC
  950 :
  960 DEFPROCpixel
  970 LOCALW%
  980 W%=2^((INSTR("QWASZ X",CHR$(A%AND223)))-1)
  990 K%=&7C00+40*VPOS+POS
 1000 IF(?K%AND160)<>160:?K%=?K%OR160
 1010 IF?(K%ANDW%)=W%:?K%=?K%AND(255-W%)ELSE?K%=?K%EORW%
 1020 ENDPROC
 1030 :
 1040 DEFPROCptog
 1050 t%=t%EOR1
 1060 IFt%:VDU23;10,&70;0;0;0 ELSE VDU23;10,&60;0;0;0
 1070 ENDPROC
 1080 :
 1090 DEFPROCleft
 1100 IFPOS>2:VDU8:ENDPROC
 1110 IFVPOS>2:VDU31,39,VPOS-1ELSEVDU7
 1120 ENDPROC
 1130 :
 1140 DEFPROCright
 1150 IFPOS<39:VDU9:ENDPROC
 1160 IFVPOS<24:VDU9,9,9ELSEVDU7
 1170 ENDPROC
 1180 :
 1190 DEFPROCdown
 1200 IFVPOS<24:VDU10ELSEVDU7
 1210 ENDPROC
 1220 :
 1230 DEFPROCup
 1240 IFVPOS>2:VDU11ELSEVDU7
 1250 ENDPROC
 1260 :
 1270 DEFPROCdelete
 1280 IFPOS=2ANDVPOS=2:VDU7:ENDPROC
 1290 org%=&7C00+40*VPOS
 1300 IFPOS=2:PROCleft ELSE FORI%=POS TO 39:?(org%+I%-1)=?(org%+I%):NEXT:VDU8
 1310 ?(&7C27+VPOS*40)=32
 1320 ENDPROC
 1330 :
 1340 DEFPROCinspc
 1350 dest%=&7C27+40*VPOS
 1360 org%=&7C00+40*VPOS+POS
 1370 diff%=dest%-org%
 1380 FORI%=0TOdiff%
 1390 ?(dest%-I%)=?(dest%-I%-1)
 1400 NEXT
 1410 ?org%=32
 1420 ENDPROC
 1430 :
 1440 DEFPROCinsline
 1450 LOCALP%
 1460 org%=&70:dest%=&74:end%=&78:stop%=&7C
 1470 !org%=&7C27+40*23
 1480 !dest%=&7C27+40*24
 1490 !end%=&7C02+40*VPOS
 1500 !stop%=&7C27+40*VPOS
 1510 FORI%=0TO2STEP2
 1520 P%=&980
 1530 [OPTI%
 1540 LDY#0
 1550 .loop
 1560 LDA(org%),Y:STA(dest%),Y
 1570 LDAorg%::BNEd1
 1580 DECorg%+1
 1590 .d1
 1600 DECorg%
 1610 LDAdest%:BNEd2
 1620 DECdest%+1
 1630 .d2
 1640 DECdest%
 1650 LDAorg%+1:CMPend%+1:BNEloop
 1660 LDAorg%:CMPend%:BCSloop
 1670 RTS
 1680 ]NEXT
 1690 CALL&980
 1700 REPEAT
 1710 ?!end%=32
 1720 !end%=!end%+1
 1730 UNTIL!end%=!stop%+1
 1740 ENDPROC
 1750 :
 1760 DEFPROCdelline
 1770 LOCALP%
 1780 org%=&70:dest%=&74:end%=&78:stop%=&7C
 1790 !org%=&7C02+40*(VPOS+1)
 1800 !dest%=&7C02+40*VPOS
 1810 !end%=&7C27+40*24
 1820 !stop%=&7C02+40*24
 1830 FORI%=0TO2STEP2
 1840 P%=&980
 1850 [OPTI%
 1860 LDY#0
 1870 .loop
 1880 LDA(org%),Y:STA(dest%),Y
 1890 INCorg%::BNEd1:INCorg%+1
 1900 .d1
 1910 INCdest%:BNEd2:INCdest%+1
 1920 .d2
 1930 LDAend%+1:CMPorg%+1:BNEloop
 1940 LDAend%:CMPorg%:BCSloop
 1950 RTS
 1960 ]NEXT
 1970 CALL&980
 1980 REPEAT
 1990 ?!end%=32
 2000 !end%=!end%-1
 2010 UNTIL!end%=!stop%-1
 2020 ENDPROC
 2030 :
 2040 DEFPROCprint
 2050 O%=&7C00:o%=0:graphic%=0:sep%=0
 2060 VDU2
 2070 IFepson%:VDU1,27,1,48
 2080 FORl%=1TO25
 2090 FORc%=1TO40
 2100 d%=?(O%+o%)
 2110 IFd%<32:d%=32
 2120 IFepson%=0 AND (d%<32ORd%>126):d%=32
 2130 IFd%>127ANDepson%:PROCeprint
 2140 IFd%=91ANDepson%:d%=0:VDU1,27,1,75,1,8,1,0,1,0,1,&10,1,&38,1,&54,1,&10,1,&10,1,&10,1,&10
 2150 IFd%=93ANDepson%:d%=0:VDU1,27,1,75,1,8,1,0,1,0,1,&10,1,&10,1,&10,1,&10,1,&54,1,&38,1,&10
 2160 VDU1,d%
 2170 o%=o%+1
 2180 NEXT
 2190 IFepson%:VDU1,10:REM LINE FEED AS REQUIRED
 2200 VDU1,13:graphic%=0:sep%=0
 2210 NEXT
 2220 IFepson%:VDU1,27,1,50
 2230 VDU1,13,3
 2240 ENDPROC
 2250 :
 2260 DEFPROCeprint
 2270 IFd%=&80:d%=32:ENDPROC
 2280 IFd%>&80 AND d%<&88:graphic%=0:d%=32:ENDPROC
 2290 IFd%>&87 AND d%<&91:d%=32:ENDPROC
 2300 IFd%>&90 AND d%<&98:graphic%=1:d%=32:ENDPROC
 2310 IFd%=&99:sep%=0
 2320 IFd%=&9A:sep%=1
 2330 IFd%>&97 AND d%<&A0:d%=32:ENDPROC
 2340 IFd%>&BF AND d%<&E0:d%=32:ENDPROC
 2350 IFgraphic%=0:d%=32:ENDPROC
 2360 PROCpixprint:d%=0
 2370 ENDPROC
 2380 :
 2390 DEFPROCpixprint
 2400 REM******* FOR EPSON PRINTER ******
 2410 flag%=0
 2420 FORn%=0TO6
 2430 flag%=flag%+(d%AND2^n%)
 2440 NEXT
 2450 :
 2460 VDU1,27,1,ASC"^",1,0,1,6,1,0
 2470 pr%=0
 2480 IFflag%AND1:pr%=pr%+&E0-(sep%*&20)
 2490 IFflag%AND4:pr%=pr%+&1C-(sep%*&04)
 2500 IFflag%AND16:pr%=pr%+&8003-(sep%*&8000)
 2510 IFsep%:VDU1,0,1,0
 2520 FORn%=sep%TO2
 2530 VDU1,pr%AND&FF
 2540 VDU1,(pr%AND&FF00)DIV&100
 2550 NEXT
 2560 pr%=0
 2570 IFflag%AND2:pr%=pr%+&E0-(sep%*&20)
 2580 IFflag%AND8:pr%=pr%+&1C-(sep%*&04)
 2590 IFflag%AND64:pr%=pr%+&8003-(sep%*&8000)
 2600 IFsep%:VDU1,0,1,0
 2610 FORn%=sep%TO2
 2620 VDU1,pr%AND&FF
 2630 VDU1,(pr%AND&FF00)DIV&100
 2640 NEXT
 2650 ENDPROC
 2660 :
 2670 DEFPROCnewpage
 2680 VDU30
 2690 FORD%=1TO24
 2700 PRINTCHR$(157)CHR$(132)STRING$(38," ");
 2710 NEXT
 2720 PRINTCHR$(157)CHR$(132)STRING$(37," ");
 2730 ?(&7C27+40*24)=32
 2740 PRINTTAB(0,1)CHR$(157)CHR$(133)"        "M$(P%)"   "STR$(year%)
 2750 PRINTCHR$(157)CHR$(132)STRING$(36,"-")
 2760 PRINTCHR$(157)CHR$(129)"Mo   Tu   We   Th   Fr   Sa   Su"
 2770 PRINTCHR$(157)CHR$(132)STRING$(36,"-")
 2780 REPEAT
 2790 PRINTCHR$(157)CHR$(133);
 2800 rl%=L%-1
 2810 FORdw%=1TO7
 2820 IFL%<10 OR L%>dd%(P%,2):PRINT" ";
 2830 IF(rl%+dw%)<dd%(P%,1)ANDL%=1 OR L%>dd%(P%,2) THEN PRINT" "; ELSE PRINTSTR$(L%);:L%=L%+1
 2840 PRINT"   ";
 2850 NEXT
 2860 PRINT
 2870 PRINTCHR$(157)CHR$(132)
 2880 PRINTCHR$(157)CHR$(132)STRING$(36,"-")
 2890 UNTILL%>dd%(P%,2)
 2900 L%=1
 2910 PRINTTAB(2,6);
 2920 ENDPROC
 2930 :
 2940 DEFPROCindex
 2950 oldL%=L%:oldP%=P%
 2960 P%=1:REPEAT:L%=1:REPEAT
 2970 PRINTTAB(0,1)CHR$(157)CHR$(133)"        "M$(P%)"   "STR$(year%)
 2980 $W%="M"+MID$(fm$,P%*3,3)
 2990 T%=0:PROCload
 3000 Q%=INKEY(100)
 3010 IFQ%=27:P%=12:L%=31
 3020 IFQ%=135:oldL%=L%:oldP%=P%:P%=12:L%=max%
 3030 IFQ%=136:IFL%>=2:L%=L%-2:Q%=0
 3040 IFQ%=136:IFL%=1ANDP%>1:P%=P%-1:L%=max%-1
 3050 IFQ%=137:IFL%<max%:L%=L%+1
 3060 IFQ%=138:IFP%>1:P%=P%-1:L%=L%-1:IFL%>max%-1:L%=max%-1
 3070 IFQ%=139:L%=max%
 3080 L%=L%+1:UNTILL%>max%:P%=P%+1:UNTILP%>12
 3090 L%=oldL%:P%=oldP%
 3100 T%=0:Q%=0
 3110 ENDPROC
 3120 :
 3130 DEFPROCload
 3140 X%=W%MOD256
 3150 Y%=W%DIV256
 3160 A%=&C0
 3170 F%=(USR&FFCE)AND&FF
 3180 PROCdisc(4,&398)
 3190 PRINTTAB(2,2);
 3200 VDU23,1,E%;0;0;0;
 3210 CLOSE#F%
 3220 ENDPROC
 3230 :
 3240 DEFPROCsave
 3250 X%=W%MOD256
 3260 Y%=W%DIV256
 3270 A%=&C0
 3280 F%=(USR&FFCE)AND&FF
 3290 T%=0
 3300 IFE%:PROCdisc(2,&398)
 3310 CLOSE#F%
 3320 F%=OPENOUT"Mdata":PRINT#F%,year%,L%,P%,epson%,sysclk%:CLOSE#F%
 3330 ENDPROC
 3340 :
 3350 DEFPROCdisc(A%,K%)
 3360 max%=EXT#F%DIV&398
 3370 REM IFS%<4:PTR#F%=(L%-1)*&398
 3380 B%?0=F%
 3390 B%!1=&7C50
 3400 B%!5=K%
 3410 X%=B%MOD256
 3420 Y%=B%DIV256
 3430 CALL&FFD1
 3440 ENDPROC
 3450 :
 3460 DEFPROCstart
 3470 REM "𓇣𙹁𠪟�6
 3480 REM "‹솬�4�5�6
 3490 E%=0:VDU23,1,0;0;0;0;
 3500 REPEAT
 3510 VDU30
 3520 PRINT"儩�                                     ";
 3530 PRINT"儩�                暆                 儩";
 3540 PRINT"儩両nstructions    暆                 儩";
 3550 PRINT"儩慲```````````    暆                 儩";
 3560 PRINT"儩両nstall your    暆                 儩";
 3570 PRINT"儩乸reprepared disc暆� j`,0 �         儩";
 3580 PRINT"儩乥efore running  暆� j  5           儩";
 3590 PRINT"儩乼he program or  暆� j  5b 6i 6!5j  儩";
 3600 PRINT"儩乮nstall a blank 暆� jp,!j e:05 ez  儩";
 3610 PRINT"儩乫ormatted disc  暆�             j  儩";
 3620 PRINT"儩乤nd select item 暆�            `!  儩";
 3630 PRINT"儩�5 to prepare a  暆�                儩";
 3640 PRINT"儩乶ew disc.       暆                 儩";
 3650 PRINT"儩乀he format of   暆                 儩";
 3660 PRINT"儩乼he disc will be暆                 儩";
 3670 PRINT"儩乨etected by the 暆                 儩";
 3680 PRINT"儩乸rogram.        暆                 儩";
 3690 PRINT"儩�                暆                 儩";
 3700 PRINT"儩�                暆                 儩";
 3710 PRINT"儩丱pen Diary      暆                 儩";
 3720 PRINT"儩丷ead Time$   NO 暆                 儩";
 3730 PRINT"儩丒pson 9pin   NO 暆                 儩";
 3740 PRINT"儩�* Command       暆                 儩";
 3750 PRINT"儩丳repare  Disc   暆                 儩";
 3760 PRINT"儩�                                    ";
 3770 IFyear%:PRINTTAB(32,5)STR$(year%)
 3780 IFsysclk%:PRINTTAB(16,20)"YES";
 3790 IFepson%:PRINTTAB(16,21)"YES";
 3800 O%=&7C00+40*19:S%=-1
 3810 REPEAT
 3820 S%=S%+1:IFS%=5:S%=0
 3830 ?(O%+S%*40)=32
 3840 Q%=GET
 3850 ?(O%+S%*40)=131
 3860 UNTILQ%=13
 3870 IFS%=0:ENDPROC
 3880 IFS%=1:sysclk%=sysclk%EOR1:PROCcmoschk
 3890 IFS%=2:epson%=epson%EOR1
 3900 IFS%=4:PROCprepdisc
 3910 UNTILFALSE
 3920 ENDPROC
 3930 :
 3940 DEFPROCprepdisc
 3950 CLS
 3960 INPUT'''" Which Year ? "year%
 3970 PRINT'''"Making a Monthly Diary for ";STR$(year%)
 3980 PRINT'"Continue Y/N ? "
 3990 Q$=GET$
 4000 IFQ$<>"Y"ANDQ$<>"y":RUN
 4010 PROCgetSDs
 4020 L%=1:P%=1
 4030 F%=OPENOUT"Mdata":PRINT#F%,year%,L%,P%,epson%,sysclk%:CLOSE#F%
 4040 B%=&900:W%=&9F0
 4050 FORP%=1TO12
 4060 file$="M"+MID$(fm$,P%*3,3)
 4070 F%=OPENOUTfile$
 4080 L%=1
 4090 PROCnewpage
 4100 PROCdisc(2,&398)
 4110 CLOSE#F%
 4120 NEXT
 4130 L%=1:P%=1:S%=0
 4140 ENDPROC
 4150 :
 4160 REM "𓇣𙹁𠪟�6
 4170 REM "‹솬�4�5�6
 4180 DEFPROChelp1
 4190 VDU30,23,1,0;0;0;0;
 4200 PRINT"潄                                      ";
 4210 PRINT"潟    j`,0          j  5                ";
 4220 PRINT"潟    j  5          jpp5   j            ";
 4230 PRINT"潟    j  5b 6i 6!5j j``5h`4j _0         ";
 4240 PRINT"潟    jp,!j e:05 ez j  5*s j u:         ";
 4250 PRINT"潟                j          5          ";
 4260 PRINT"潟               `!          !          ";
 4270 PRINT"潄                                      ";
 4280 PRINT"潄 View Mode         Cursor OFF         ";
 4290 PRINT"潄慲````````                            ";
 4300 PRINT"潄    H.....This help                   ";
 4310 PRINT"潄    I.....Index see next page         ";
 4320 PRINT"潄    P.....Print Page                  ";
 4330 PRINT"潄 <['>.....Enter edit mode             ";
 4340 PRINT"潄<Esc>.....Close the Diary             ";
 4350 PRINT"潄                                      ";
 4360 PRINT"潄 Edit Mode         Cursor ON          ";
 4370 PRINT"潄慲````````                            ";
 4380 PRINT"潄Once here any changes you make will   ";
 4390 PRINT"潄be saved on leaving i.e. after  you   ";
 4400 PRINT"潄hit <Esc>, no prompt is asked for     ";
 4410 PRINT"潄before saving, so should you not wish ";
 4420 PRINT"潄to save the changes you have made hit ";
 4430 PRINT"潄the <Break> key.                      ";
 4440 PRINT"潄                                     ";
 4450 ?(&7C27+40*24)=32
 4460 Q%=GET
 4470 IFQ%<>27:PROChelp2
 4480 H%=1:Q%=13
 4490 ENDPROC
 4500 :
 4510 REM "𓇣𙹁𠪟�6
 4520 REM "‹솬�4�5�6
 4530 DEFPROChelp2
 4540 PRINTTAB(0,7);
 4550 PRINT"潄 INDEX                                ";
 4560 PRINT"潄慲````                                ";
 4570 PRINT"潄Cycles through the whole Diary        ";
 4580 PRINT"潄use the cursor keys to jump :-        ";
 4590 PRINT"潄                                      ";
 4600 PRINT"潄 Left...back a month                  ";
 4610 PRINT"潄                                      ";
 4620 PRINT"潄Right...forward a month               ";
 4630 PRINT"潄                                      ";
 4640 PRINT"潄 Down...back a month                  ";
 4650 PRINT"潟                                      ";
 4660 PRINT"潄   Up...forward a month               ";
 4670 PRINT"潄                                      ";
 4680 PRINT"潄 <Copy> Exit to current date          ";
 4690 PRINT"潄                                      ";
 4700 PRINT"潄<Escape> Exit returning to the        ";
 4710 PRINT"潄         intitial date                ";
 4720 PRINT"潄                                     ";
 4730 Q%=GET
 4740 IFQ%<>27:PROChelp3
 4750 H%=1:Q%=13
 4760 ENDPROC
 4770 :
 4780 REM "𓇣𙹁𠪟�6
 4790 REM "‹솬�4�5�6
 4800 DEFPROChelp3
 4810 PRINTTAB(0,7);
 4820 PRINT"潄 Function Keys 1                      ";
 4830 PRINT"潄慲``````````````                      ";
 4840 PRINT"潄  Ctrl+C....Clear Screen              ";
 4850 PRINT"潄  Ctrl+P....Print page                ";
 4860 PRINT"潄                                      ";
 4870 PRINT"潄       f0...Red text                  ";
 4880 PRINT"潄       f1...Green text                ";
 4890 PRINT"潄       f2...Yellow text               ";
 4900 PRINT"潄       f3...Blue text                 ";
 4910 PRINT"潄       f4...Magenta text              ";
 4920 PRINT"潄       f5...Cyan text                 ";
 4930 PRINT"潄       f6...White text                ";
 4940 PRINT"潄       f7...Flashing                  ";
 4950 PRINT"潄       f8...Steady                    ";
 4960 PRINT"潄       f9...Pixel editor              ";
 4970 PRINT"潄                                      ";
 4980 PRINT"潄    <Esc>...Save, Return to View Mode ";
 4990 PRINT"潄                                     ";
 5000 Q%=GET
 5010 IFQ%<>27:PROChelp4
 5020 H%=1:Q%=13
 5030 ENDPROC
 5040 :
 5050 REM "𓇣𙹁𠪟�6
 5060 REM "‹솬�4�5�6
 5070 DEFPROChelp4
 5080 PRINTTAB(0,7);
 5090 PRINT"潄 Function Keys 2                      ";
 5100 PRINT"潄慲``````````````                      ";
 5110 PRINT"潄  Ctrl+C....Clear Screen              ";
 5120 PRINT"潄  Ctrl+P....Print page                ";
 5130 PRINT"潄                                      ";
 5140 PRINT"潄 Shift+f0...Red graphics              ";
 5150 PRINT"潄 Shift+f1...Green graphics            ";
 5160 PRINT"潄 Shift+f2...Yellow graphics           ";
 5170 PRINT"潄 Shift+f3...Blue graphics             ";
 5180 PRINT"潄 Shift+f4...Magenta graphics          ";
 5190 PRINT"潄 Shift+f5...Cyan graphics             ";
 5200 PRINT"潄 Shift+f6...White graphics            ";
 5210 PRINT"潄 Shift+f7...Black background          ";
 5220 PRINT"潄 Shift+f8...Colour background         ";
 5230 PRINT"潄 Shift+f9...Pixel editor              ";
 5240 PRINT"潄                                      ";
 5250 PRINT"潄    <Esc>...Save, Return to View Mode ";
 5260 PRINT"潄                                     ";
 5270 Q%=GET
 5280 IFQ%<>27:PROChelp5
 5290 H%=1:Q%=13
 5300 ENDPROC
 5310 :
 5320 REM "𓇣𙹁𠪟�6
 5330 REM "‹솬�4�5�6
 5340 DEFPROChelp5
 5350 PRINTTAB(0,7);
 5360 PRINT"潄 Function Keys 3                      ";
 5370 PRINT"潄慲``````````````                      ";
 5380 PRINT"潄  Ctrl+C....Clear Screen              ";
 5390 PRINT"潄  Ctrl+P....Print page                ";
 5400 PRINT"潄                                      ";
 5410 PRINT"潄  Ctrl+f0...Contiguous graphics       ";
 5420 PRINT"潄  Ctrl+f1...Seperated graphics        ";
 5430 PRINT"潄  Ctrl+f2...Hold graphics             ";
 5440 PRINT"潄  Ctrl+f3...Release graphics          ";
 5450 PRINT"潄  Ctrl+f4...Double height             ";
 5460 PRINT"潄  Ctrl+f5...Single height             ";
 5470 PRINT"潄  Ctrl+f6...Insert space              ";
 5480 PRINT"潄  Ctrl+f7...Insert line 刣issabled    ";
 5490 PRINT"潄  Ctrl+f8...Delete line 刣issabled    ";
 5500 PRINT"潄  Ctrl+f9...Pixel editor              ";
 5510 PRINT"潄                                      ";
 5520 PRINT"潄    <Esc>...Save, Return to View Mode ";
 5530 PRINT"潄                                     ";
 5540 Q%=GET
 5550 ENDPROC
 5560 :
 5570 DEFPROCoscli
 5580 CLS:PRINT"*";:INPUT""L$:OSCLIL$
 5590 PRINT'"Hit Any Key":Q%=GET:RUN
 5600 ENDPROC
 5610 :
 5620 DEFPROCinit
 5630 CLS
 5640 t%=0
 5650 B%=&900:W%=&9F0
 5660 T%=0:M%=0
 5670 $&A00=CHR$(157)+CHR$(132)+STRING$(38," ")
 5680 IFsysclk%:PROCcmoschk
 5700 ENDPROC
 5710 :
 5720 DEFPROCgetSDs
 5730 Y4=INT(year%/4)
 5740 SD=year%+Y4-7*INT((year%+Y4)/7)
 5750 IFSD<1:SD=7
 5760 SD=SD-1
 5770 IFSD<1:SD=7
 5780 IFyear%=4*Y4:SD=SD-1:dd%(2,2)=29
 5790 FORI=1TO12
 5800 dd%(I,1)=SD
 5810 FORN=1TOdd%(I,2)
 5820 SD=SD+1:IFSD>7:SD=1
 5830 NEXT
 5840 NEXT
 5850 ENDPROC
 5860 :
 5870 DEFPROCcmoschk
 5880 T$=TIME$:D$=MID$(T$,5,2):M$=MID$(T$,8,3)
 5890 L%=1:P%=INSTR(fm$,M$)/3
 5900 IFP%:ENDPROC
 5910 CLS
 5920 PRINT"There is something wrong with your"
 5930 PRINT"CMOS memory! Check it with TIME$ it may"
 5940 PRINT"need resetting or your battaries may"
 5950 PRINT"need replacing. If you cannot fix it"
 5960 PRINT"then do not try to set the CMOS option"
 5970 END
 5980 ENDPROC
 5990 :
 6000 DEFPROCfinish
 6010 A%=0:Y%=0:CALL&FFCE
 6020 *FX4,0
 6030 *FX229,0
 6040 VDU23;10,&70;0;0;0
 6050 END
 6060 ENDPROC
 6070 :
 6080 DATA"  January",31
 6090 DATA" February",28
 6100 DATA"    March",31
 6110 DATA"    April",30
 6120 DATA"      May",31
 6130 DATA"     June",30
 6140 DATA"     July",31
 6150 DATA"   August",31
 6160 DATA"September",30
 6170 DATA"  October",31
 6180 DATA" November",30
 6190 DATA" December",31